Star Trek Starfleet Academy Mini Omnipedia/MINI_OMNI.ISO/pc/omni_v2.dxr/00385_MIAW handlers for PICTs and VIDEO.ls

Text File | 1996-04-15 | 8.3 KB | 298 lines

global gMyWinList, gTheWindowRect, gMyQTwindow, gQTWinActive, gwinCheck, gWinListNum, gTheName, gTheNewWinht, gTheNewWinwd, gMyWinTracker, gMyWindow, gtheLockList, gImageList, gthumbn1spr, gthumbn2spr, gthumbn3spr, gthumbn4spr, gthumbn5spr, gVideoName, gPDL, gtheWord, gWinType, gNewCaption, gCaptionList, gAssetPath, gComputerTypeK, gthumbholdcst, gTrekCursor, oWinKey, gModeState, gActiveResTopWin, gActiveTopWin, gMacColorIsHere, gWinTypeList, gActiveWin, glinktostagemsg, gLockWinStorage, oPWin, gVidIsPlaying, gWinOffSet, gLastWinLeft, gLastWinTop, gSpriteList, gWinLocRootT, gWinLocRootL, gWinLocCounter, gLastResWinLeft, gLastResWinTop

on hInitMinaWLists
  set gWinListNum to 0
  set gMyWinList to [:]
  set gMyWinTracker to [:]
  set gtheLockList to [:]
  set gImageList to [:]
  set gWinTypeList to [:]
  set gSpriteList to [:]
  set the windowList to []
  set gVidIsPlaying to 0
  set gWinOffSet to 6
  set gLockWinStorage to []
  set gLastWinLeft to the stageLeft + 330
  set gLastWinTop to the stageTop + 172
  set gLastResWinLeft to the stageLeft + 160
  set gLastResWinTop to the stageTop + 200
  set gWinLocRootL to gLastWinLeft
  set gWinLocRootT to gLastWinTop
  set gWinLocCounter to 1
  set the fileName of cast the number of cast "BlankM.DIR" to the pathName & "BL" & gPDL & "BlankM.DIR"
  repeat with n = 1 to 15
    addProp(gMyWinList, n, EMPTY)
    addProp(gImageList, n, EMPTY)
    addProp(gWinTypeList, n, #CLOSED)
    addProp(gMyWinTracker, n, 0)
    addProp(gtheLockList, n, 0)
    addProp(gSpriteList, n, 0)
  end repeat
  if gComputerTypeK = #WIN then
    set gWinType to 49
  else
    set gWinType to 16
  end if
end

on hHelpWinClose
  repeat with a = 1 to 15
    if getaProp(gtheLockList, a) = 0 then
      set vWinToLose to string(getaProp(gMyWinList, a))
      if gActiveResTopWin = vWinToLose then
        hCloseTopWin()
      end if
      forget(window vWinToLose)
      setAt(gMyWinTracker, a, 0)
      setAt(gMyWinList, a, EMPTY)
      setAt(gImageList, a, EMPTY)
      setAt(gWinTypeList, a, #CLOSED)
    end if
    hClearTopic()
  end repeat
end

on hUpdateWin
  repeat with a = 1 to 15
    if getaProp(gtheLockList, a) = 0 then
      set vWinToLose to string(getaProp(gMyWinList, a))
      if gActiveResTopWin = vWinToLose then
        hCloseTopWin()
      end if
      forget(window vWinToLose)
      setAt(gMyWinTracker, a, 0)
      setAt(gMyWinList, a, EMPTY)
      setAt(gImageList, a, EMPTY)
      setAt(gWinTypeList, a, #CLOSED)
    end if
  end repeat
  hClearPicons()
  hClearTopic()
end

on hClearPicons
  set the visible of sprite gthumbn1spr to 1
  set the visible of sprite gthumbn2spr to 1
  set the visible of sprite gthumbn3spr to 1
  set the visible of sprite gthumbn4spr to 1
  set the visible of sprite gthumbn5spr to 1
end

on hHidePicons
  repeat with x = gthumbn1spr to gthumbn5spr
    set the visible of sprite x to 0
  end repeat
end

on hClearTopic
  if gModeState <> #TOPICS then
    if not voidp(gActiveResTopWin) then
      forget(window string(gActiveResTopWin))
    end if
  end if
end

on hClearResourseMiaw
  if not voidp(gActiveResTopWin) then
    forget(window string(gActiveResTopWin))
  end if
end

on hStoreLockWins
  set gLockWinStorage to []
  set vPriorLeft to 1600
  set vPriorTop to 1600
  repeat with a = 1 to 15
    if getaProp(gtheLockList, a) = 1 then
      set vWinToLose to string(getaProp(gMyWinList, a))
      add(gLockWinStorage, getAt(gImageList, a))
      set vWinRect to the rect of window vWinToLose
      put vWinRect
      if getAt(vWinRect, 1) < vPriorLeft then
        set vPriorLeft to getAt(vWinRect, 1)
        set vPriorTop to getAt(vWinRect, 2)
      end if
      tell window vWinToLose
        mDoCloseWindow(oPWin)
      end tell
      setAt(gtheLockList, a, 0)
      setAt(gMyWinTracker, a, 0)
      setAt(gMyWinList, a, EMPTY)
      setAt(gImageList, a, EMPTY)
      setAt(gWinTypeList, a, #CLOSED)
    end if
  end repeat
  if vPriorLeft < 1600 then
    set gLastWinLeft to vPriorLeft
    set gLastWinTop to vPriorTop
  end if
end

on hRestoreLockWins
  set x to count(gLockWinStorage)
  if x then
    repeat with vWinNum = 1 to x
      hOpenLockWin(getAt(gLockWinStorage, vWinNum))
      setAt(gtheLockList, gWinListNum, 1)
    end repeat
  end if
  hHideOpenPicons()
  repeat with vWinNum = 1 to x
    tell window getAt(gMyWinList, vWinNum)
      mForceLockMe(oPWin)
    end tell
  end repeat
  set gLockWinStorage to []
end

on hOpenLockWin pPictName
  hSysAlert(#MEDIALINK)
  set gTheName to pPictName
  hGetPICTWinNum()
  hgetCaption()
  if getAt(gMyWinTracker, gWinListNum) = 0 then
    if (gWinListNum > 0) and (gWinListNum < 11) then
      hActivateMIAW(the pathName & "BL" & gPDL & gWinListNum & "PicWn.dir", gWinListNum)
    end if
    set vNewWinName to getAt(gMyWinList, gWinListNum)
    open(window vNewWinName)
    hCallOmniColor()
    moveToFront(window vNewWinName)
    tell window vNewWinName
      mStartUp(oPWin)
    end tell
    tell window vNewWinName
      mForceLockMe(oPWin)
    end tell
    tell window vNewWinName
      mSetbasicWinKeys(oWinKey, window vNewWinName)
    end tell
    tell window vNewWinName
      mSetBasicMouseUp(oWinKey, window vNewWinName)
    end tell
    set gLastWinLeft to getAt(the rect of window vNewWinName, 1) + gWinOffSet
    set gLastWinTop to getAt(the rect of window vNewWinName, 2) + gWinOffSet
  end if
end

on hOpenPict pMySprite
  global oVidCD
  if the castNum of sprite pMySprite <> gthumbholdcst then
    if mCheckForHomeCD(oVidCD, "hOpenPict " & string(pMySprite)) then
      hSysAlert(#MEDIALINK)
      hOpenWhichImage(pMySprite)
      hGetPICTWinNum()
      setAt(gSpriteList, gWinListNum, pMySprite)
      set the visible of sprite pMySprite to 0
      updateStage()
      hgetCaption()
      if getAt(gMyWinTracker, gWinListNum) = 0 then
        if (gWinListNum > 0) and (gWinListNum < 11) then
          hActivateMIAW(the pathName & "BL" & gPDL & gWinListNum & "PicWn.dir", gWinListNum)
        end if
        set vNewWinName to getAt(gMyWinList, gWinListNum)
        open(window vNewWinName)
        hCallOmniColor()
        moveToFront(window vNewWinName)
        tell window vNewWinName
          mStartUp(oPWin)
        end tell
        tell window vNewWinName
          mSetbasicWinKeys(oWinKey, window vNewWinName)
        end tell
        tell window vNewWinName
          mSetBasicMouseUp(oWinKey, window vNewWinName)
        end tell
        set gLastWinLeft to getAt(the rect of window vNewWinName, 1) + gWinOffSet
        set gLastWinTop to getAt(the rect of window vNewWinName, 2) + gWinOffSet
        hCheckWinLocCounter()
      end if
    end if
  end if
end

on hOpenWhichImage pMySprite
  set Lmynum to the castNum of sprite pMySprite
  if Lmynum = gthumbholdcst then
    abort()
  end if
  set zz to the name of cast Lmynum
  set gTheName to chars(string(zz), 1, 7)
  repeat with y = 1 to 10
    if getaProp(gImageList, y) = gTheName then
      beep()
      abort()
    end if
  end repeat
end

on hOpenWhichResImage pImageName
  set gTheName to chars(pImageName, 1, 7)
  set vIsNewImage to 1
  if getOne(gImageList, gTheName) then
    set vIsNewImage to 0
    set glinktostagemsg to EMPTY
    abort()
  end if
  return vIsNewImage
end

on hGetPICTWinNum
  repeat with a = 1 to 10
    if getaProp(gMyWinTracker, a) = 1 then
      if a = 10 then
        hAnnounce("Max Num. Images open...")
        abort()
      end if
      next repeat
    end if
    set gWinListNum to a
    exit repeat
  end repeat
end

on hOpenVideo
  hSysAlert(#MEDIALINK)
  hOpenWhichVid()
  hGetVidWinNum()
  hGetVidCap()
  if (gWinListNum > 10) and (gWinListNum < 16) then
    if gComputerTypeK = #WIN then
      hActivateMIAW(the pathName & "BL" & gPDL & gWinListNum & "VIDWNW.DIR", gWinListNum)
    else
      hActivateMIAW(the pathName & "BL" & gPDL & gWinListNum & "VidWn.dir", gWinListNum)
    end if
  end if
  set vNewWinName to getAt(gMyWinList, gWinListNum)
  open(window vNewWinName)
  hCallOmniColor()
  moveToFront(window vNewWinName)
  tell window vNewWinName
    mSetbasicWinKeys(oWinKey, window vNewWinName)
  end tell
  tell window vNewWinName
    mSetBasicMouseUp(oWinKey, window vNewWinName)
  end tell
end

on hOpenWhichVid
  global gNopeSND
  set gTheName to gVideoName
  set y to 11
  if getaProp(gImageList, y) = gTheName then
    hearit(gNopeSND)
    abort()
  end if
end

on hGetVidWinNum
  global gNopeSND
  set a to 11
  if getaProp(gMyWinTracker, a) = 1 then
    hearit(gNopeSND)
    abort()
  else
    set gWinListNum to a
  end if
end